# Mixed first-order and zero-order absorption, or parallel first-order

Some drugs can display complex absorption kinetics. Common examples are mixed first-order and zero-order absorptions, where one fraction of the dose is absorbed via one route and the other fraction via another route, either simultaneously or with one of the route showing a delay. Another example is fast and slow first-order absorptions in parallel. Finally, sequential absorption with a zero-order process into a transit compartment followed by a first-order absorption in the central compartment is also possible.

A few examples of those kinds of absorption kinetics are listed below:

**parallel first-order:**oral sustained-release Diltiazem (Murata et al. 1989) and sublingual doses with a rapid absorption from the bucal cavity followed by a delayed absorption from the gastrointestinal tract (“Pharmacokinetic and Pharmacodynamic Data Analysis: Concepts and Applications” by Gabrielsson and Weiner)**first-order followed by zero-order**: oral sumatriptan (Cosson et al. 1999)**zero-order followed by first-order**: oral cefadroxil (Guarrigues et al. 1991)

More examples of complex absorptions are given in:

### Mlxtran models

For the examples below, we consider a single compartment and a linear elimination. The model is described using macros. When two absorption routes are considered, a fraction F of the dose is absorbed via the one process and the remaining 1-F fraction of the dose is absorbed via another process. **In the data set, the dose lines must ****not**** be duplicated**. A single dose line can be split into two processes using the keyword p in the absorption macros.

As the parameter F must stay within [0,1], a logit distribution must be chosen in the Monolix GUI.

#### Sequential absoption

In this model, the drug is first absorbed via a zero-order process into a transit compartment and then transferred from the transit compartment into the central compartment using a first-order process. This model allows to capture a progressively faster increase of the concentration during the absorption phase with a simpler model than when taking into account an estimated number of transit compartments (absorption macro with Mtt and Ktr parameters). In addition, this model has the advantage of using an analytical solution, so it is faster to run than a model with estimated transit compartmet that require the solve an ODE system. For the analytical solution to be used, a dummy elimination (equal to zero) from the transit compartment is necessary.

```
[LONGITUDINAL]
input = {Tk0, ka, V, Cl}
PK:
compartment(cmt = 1, amount = Ad)
oral(cmt = 1, Tk0)
elimination(cmt = 1, Cl=0) ; dummy elimination term
compartment(cmt = 2, volume = V, concentration = Cc)
transfer(from = 1, to = 2, kt = ka)
elimination(cmt = 2, Cl)
OUTPUT:
output = {Cc}
```

This model is not yet available in the Monolix libraries.

#### Parallel first-order

Parallel first-order absorptions can have various causes, among other: absorption via water and lipid routes for dermal administrations, absorption in the bucal cavity and GI tract for sublingual administrations, progressive solubilisation along the GI tract and subsequent intestinal absorption for oral administrations or simply two different absorption sites.

```
[LONGITUDINAL]
input = {ka1, ka2, Tlag, F, V, Cl}
PK:
compartment(cmt=1, volume=V, concentration=Cc)
absorption(cmt=1, ka=ka1, p=F)
absorption(cmt=1, ka=ka2, Tlag, p=1-F)
elimination(cmt=1, Cl)
OUTPUT:
output = {Cc}
```

This model is available in the PK double absorption library, with the name *oral1_oral1_1cpt_ka1ka2F1Tlag2VCl.txt*, with Tlag named Tlag2 and F named F1.

#### Simultaneous zero-order and first-order

The drug is simultaneously absorbed via a first-order and a zero-order process, which both start at the administration time (no lag time).

```
[LONGITUDINAL]
input = {ka, Tk0, F, V, Cl}
PK:
compartment(cmt=1, volume=V, concentration=Cc)
absorption(cmt=1, Tk0, p=F)
absorption(cmt=1, ka, p=1-F)
elimination(cmt=1, Cl)
OUTPUT:
output = {Cc}
```

This model is available in the PK double absorption library, with the name *oral0_oral1_1cpt_Tk01ka2F1VCl.txt*, with Tk0 named Tk01, ka named ka2, and F named F1.

#### Sequential zero-order followed by first order

The drug is first absorbed via a zero-order process during a time Tk0. Once this is finished, the remaining fraction is absorbed via a first-order process, which starts with a lag time Tk0.

```
[LONGITUDINAL]
input = {ka, Tk0, F, V, Cl}
PK:
compartment(cmt=1, volume=V, concentration=Cc)
absorption(cmt=1, Tk0, p=F)
absorption(cmt=1, Tlag=Tk0, ka, p=1-F)
elimination(cmt=1, Cl)
OUTPUT:
output = {Cc}
```

This model is available in the PK double absorption library, with the name *oral0_oral1_seqAbs_1cpt_Tk01ka2F1VCl.txt*, with Tk0 named Tk01, ka named ka2, and F named F1.

#### Sequential first-order followed by zero-order

Because a first-order absorption never ends (there is always a little bit of drug remaining in the depot compartment and being absorbed into the central compartment), the two absorption processes will not be truly sequential. Yet **we can introduce a lag time for the zero-order process**, such that the zero-order process starts when the first-order process becomes negligible.

```
[LONGITUDINAL]
input = {ka, Tk0, F, Tlag, V, Cl}
PK:
compartment(cmt=1, volume=V, concentration=Cc)
absorption(cmt=1, Tk0, p=F, Tlag)
absorption(cmt=1, ka, p=1-F)
elimination(cmt=1, Cl)
OUTPUT:
output = {Cc}
```

This model is available in the PK double absorption library, with the name *oral1_oral0_1cpt_ka1Tk02F1Tlag2VCl.txt*, with ka named ka1, Tk0 named Tk0*2*, Tlag named Tlag2, and F named F1.

#### Two administration routes and mixed absorption

Below we present a model for an administration scheme with two different routes: some doses are administrated via iv and some orally. **The two routes are distinguished using an identifier**: in the data set the doses are tagged using the ADM column with either ADM=1 (iv for instance) or ADM=2 (oral). In the model, the adm keyword is used to associate a route to specific doses.

In addition, we introduce the total bioavailability for the oral route Foral.

```
[LONGITUDINAL]
input = {ka, Tk0, F, Foral, Tlag, V, Cl}
PK:
compartment(cmt=1, volume=V, concentration=Cc)
iv(adm=1, cmt=1)
absorption(adm=2, cmt=1, Tk0, p=F*Foral, Tlag)
absorption(adm=2, cmt=1, ka, p=(1-F)*Foral)
elimination(cmt=1, Cl)
OUTPUT:
output = {Cc}
```