DESCRIPTION:

[LONGITUDINAL]
input={F, D50, TLAG, KA, V, CLpop, etaCL, KDEG, PCSK90, KSS, KINT, KOUT, LDLC0, IMAX, IC50, DOSEMG}
DOSEMG = {use=regressor}

PK:
BIO = F * D50/(D50+DOSEMG)
depot(adm=1, target=A1, p=BIO/144*1000, Tlag=TLAG) 

EQUATION:
odeType = stiff
odeRelTol = 1e-6 ; default value

CL = CLpop * (1+etaCL)

KEL  = CL/V
KSYN = KDEG*PCSK90           
INH0 = (IMAX*PCSK90)/(IC50+PCSK90)
KIN  = KOUT*(1-INH0)*LDLC0    

A3_0 = PCSK90     ; change initial condition from default of zero
A4_0 = LDLC0      ; change initial condition from default of zero

TDC = A2/V                                                 
FDC = 0.5*((TDC-A3-KSS) + sqrt((TDC-A3-KSS)^2 + 4*KSS*TDC))
FLC = A3 - (TDC - FDC)                                     

ddt_A1 = -KA*A1                                          
ddt_A2 =  KA*A1 - KEL*FDC*V - (KINT*A3*FDC*V)/(KSS+FDC)  
ddt_A3 =  KSYN - KDEG*A3 - ((KINT-KDEG)*FDC*A3)/(KSS+FDC)

INH = (IMAX*PCSK90)/(IC50+PCSK90)
if t>0
INH = (IMAX*FLC)/(IC50+FLC)
end

ddt_A4 = KIN - KOUT*(1-INH)*A4   

FDCscaled = FDC*144/1000	; convert nM to mcg/mL, approximate MW of evolocumab is 144 kDa 

OUTPUT:
output = {FDCscaled, FLC, A4}