Supplementary appendix S2 Final model code

Supplement to:

Title: A population pharmacokinetic model incorporating saturable pharmacokinetics and auto-induction for high rifampicin doses

Authors: Robin J Svensson (1), Rob E Aarnoutse (2), Andreas H Diacon (3), Rodney Dawson (4), Stephen H Gillespie (5), Martin J Boeree (6) and Ulrika SH Simonsson (1)

Affiliations: (1) Department of Pharmaceutical Biosciences, Uppsala University, Uppsala, Sweden, (2) Department of Pharmacy, Radboud University Medical Center, Nijmegen, the Netherlands, (3) DST/NRF Centre of Excellence for Biomedical Tuberculosis Research and MRC Centre for TB Research, Division of Molecular Biology and Human Genetics, Stellenbosch University, Tygerberg, South Africa and TASK Applied Sciences, Cape Town, South Africa, (4) Department of Respiratory Medicine, University of Cape Town, Cape Town, South Africa and The Lung Institute, Cape Town, South Africa (5) School of Medicine, University of St. Andrews, St. Andrews Fife, United Kingdom, (6) Department of Lung Diseases, Radboud University Medical Center, Nijmegen, the Netherlands and University Centre for Chronic Diseases Dekkerswald, Groesbeek, the Netherlands

Correspondence: USH Simonsson (ulrika.simonsson@farmbio.uu.se)

$PROBLEM FINAL POPULATION PK MODEL HIGHRIF1  
$ABBREVIATED DERIV2=NOCOMMON  
$INPUT ID TIME TADO DGRP DV BQL AMT EVID OCC PLOT AGE SEX RACE WT HT BMI HIV FFM NDV DOSE

; TIME=hours, TADO=time after last dose, DGRP=dose in mg/kg, BQL (0=observation is not BLOQ, 1=observation is BLOQ, 2=observation missing, 3=dummy or dosing time point), OCC (1=day 7, 2=day 14), PLOT=flag variable for creating VPCs, SEX (1=male, 0=female), FFM=fat free mass in kg, DOSE=dose in mg

$DATA ... IGNORE=@  
$SUBROUTINE ADVAN13 TRANS1 TOL=10  
$MODEL NCOMP = 3 COMP = (DEPOT,DEFDOSE) COMP = (CENTRAL,DEFOBS) COMP = (ENZ)  
$PK  
"FIRST  
" COMMON/PRCOMG/ IDUM1,IDUM2,IMAX,IDUM4,IDUM5  
" INTEGER IDUM1,IDUM2,IMAX,IDUM4,IDUM5  
" IMAX=1000000000

; Needed for the transit absorption compartment model  
IF(AMT.GT.0)PD = AMT ; PD = oral DOSE  
IF(AMT.GT.0)TDOS = TIME ; TDOS = time of DOSE  
TAD = TIME - TDOS ; TAD = time after DOSE

;----Allometric scaling using fat-free mass-----  
NFMCL = FFM  
ALLMCL = (NFMCL/70)\*\*0.75

NFMV = FFM  
ALLMV = (NFMV/70)

;----Typical parameters-------------------------  
TVVMAX = THETA(1) ; VMAX (MG/H/70KG)  
TVKM = THETA(2) ; KM (MG/L)  
TVV2 = THETA(3)\*ALLMV ; V2 (L/70KG)  
TVKA = THETA(4) ; KA (H-1)  
TVEMAX = THETA(5) ; EMAX  
TVEC50 = THETA(6) ; EC50 (MG/L)  
TVKENZ = THETA(7) ; KENZ (H-1)  
TVMTT = THETA(8) ; MTT (H)  
TVNN = THETA(9) ; NN  
TVFEMAX = THETA(10) ; FEMAX  
TVFED50 = THETA(11) ; ED50 (MG)

;----Inter-occasion variability-----------------  
IF (OCC.EQ.1) THEN  
 IOVBIO = ETA(7)  
 ELSE  
 IOVBIO = ETA(8)  
ENDIF

IF (OCC.EQ.1) THEN  
 IOVMTT = ETA(9)  
 ELSE  
 IOVMTT = ETA(10)  
ENDIF

IF (OCC.EQ.1) THEN  
 IOVKM = ETA(11)  
 ELSE  
 IOVKM = ETA(12)  
ENDIF

IF (OCC.EQ.1) THEN  
 IOVKA = ETA(13)  
 ELSE  
 IOVKA = ETA(14)  
ENDIF

;----Individual parameters----------------------  
VMAX = TVVMAX\*EXP(ETA(2))  
KM = TVKM\*EXP(ETA(1)+IOVKM)  
V2 = TVV2\*EXP(ETA(3))  
KA = TVKA\*EXP(ETA(6)+IOVKA)  
EC50 = TVEC50  
EMAX = TVEMAX  
KENZ = TVKENZ  
FEMAX = TVFEMAX  
FED50 = TVFED50  
TVBIO = 1\*(1+FEMAX\*(DOSE-450)/(FED50+(DOSE-450)))  
BIO = TVBIO\*EXP(IOVBIO)  
K = CL/V2  
MTT = TVMTT\*EXP(ETA(4)+IOVMTT)  
NN = TVNN\*EXP(ETA(5))  
S2 = V2

;---INITIALIZATION OF COMPARTMENTS---------------  
F1 = 0 ; TRANSIT ABSORPTION COMPARTMENT  
A\_0(2) = 0.0001 ; CENTRAL COMPARTMENT  
A\_0(3) = 1 ; INDUCTION COMPARTMENT

KTR = (NN + 1) / MTT

;----Logarithm of the approximation to the gamma function  
L = 0.9189385 + (NN + 0.5)\*LOG(NN) - NN + LOG(1 + 1/(12\*NN))  
LBPD = LOG(BIO\*PD)  
LKTR = LOG(KTR)  
CUMUL = LBPD + LKTR - L

$DES  
CP = A(2)/V2 ; RIFAMPICIN PLASMA CONCENTRATION (MG/L)

TEMPO = T – TDOS  
 IF(TEMPO.GT.0)THEN  
 KTT = KTR\*TEMPO  
 DADT(1) = EXP(CUMUL + NN\*LOG(KTT) - KTT) - KA\*A(1)  
 ELSE  
 KTT = 0  
 DADT(1) = 0  
 ENDIF

DADT(2) = KA\*A(1) - (((VMAX/(KM+CP))\*ALLMCL)/V2)\*A(2)\*A(3)  
EFF = (EMAX\*(CP)) / (EC50 + CP)  
DADT(3) = KENZ\*(1 + EFF) - KENZ\*A(3)

$ERROR  
IPRED = LOG(A(2)/S2+0.00001) ; CONCENTRATION IN CENTRAL COMPARTMENT (LOG TRANSFORMED)  
ADD = SQRT(SIGMA(1,1)) ; ADD ERROR WITH LOG DV (APPROXIMATES PROP ERROR ON THE NORMAL SCALE)  
SD = SQRT((ADD)\*\*2)

;Sim\_start  
LLOQ=LOG(0.13)

DUM=(LLOQ-IPRED)/SD  
CUMD=PHI(DUM)

IF(DV.GE.LLOQ) THEN  
F\_FLAG = 0  
IRES = DV – IPRED  
IWRES = IRES / SD  
Y = IPRED + EPS(1)  
ELSE  
F\_FLAG = 1  
IRES = 0  
IWRES = 0  
MDVRES = 1  
Y=CUMD  
ENDIF

;IRES = DV – IPRED  
;IWRES = IRES / SD  
;Y = IPRED + EPS(1)  
;Sim\_end

;----Output--------------------------------------  
AA1 = A(1) ; ABSORPTION COMPARTMENT  
AA2 = A(2) ; CENTRAL RIFAMPICIN COMPARTMENT  
AA3 = A(3) ; INDUCTION COMPARTMENT

IF(AMT.GT.0) THEN  
 TDOS = TIME  
 PD = AMT  
ENDIF

$THETA (0, 5.25E+02) ; 1 VMAX  
$THETA (0, 3.53E+01) ; 2 KM  
$THETA (0, 8.72E+01) ; 3 V2  
$THETA (0, 1.77E+00) ; 4 KA  
$THETA (0, 1.16E+00) ; 5 EMAX  
$THETA (0, 6.99E-02) ; 6 EC50  
$THETA (0, 6.03E-03) ; 7 KENZ  
$THETA (0, 5.13E-01) ; 8 MTT  
$THETA (1, 2.38E+01) ; 9 NN  
$THETA (0, 5.04E-01) ; 10 FEMAX  
$THETA (0, 6.70E+01) ; 11 FED50  
$OMEGA BLOCK(2)  
1.28E-01 ; 1 IIV in KM  
4.18E-02 9.01E-02 ; 2 IIV IN VMAX  
$OMEGA 6.18E-03 ; 3 IIV in V2  
$OMEGA 1.46E-01 ; 4 IIV in MTT  
$OMEGA 6.07E-01 ; 5 IIV in NN  
$OMEGA 1.14E-01 ; 6 IIV in KA  
$OMEGA BLOCK(1) 2.48E-02 ; 7 IOV in F  
$OMEGA BLOCK(1) SAME  
$OMEGA BLOCK(1) 3.18E-01 ; 9 IOV in MTT  
$OMEGA BLOCK(1) SAME  
$OMEGA BLOCK(1) 3.55E-02 ; 11 IOV in KM  
$OMEGA BLOCK(1) SAME  
$OMEGA BLOCK(1) 9.85E-02 ; 13 IOV in KA  
$OMEGA BLOCK(1) SAME  
$SIGMA 5.55E-02 ; ADD ERROR

;Sim\_start  
$ESTIMATION METHOD=1 LAPLACIAN INTER NUMERICAL SLOW MAXEVAL=9999 NSIG=3 SIGL=9 PRINT=3 MCETA=100  
$COVARIANCE PRINT=E MATRIX=S SLOW  
;$SIMULATION (1234) ONLYSIM  
;Sim\_end  
$TABLE ID IPRED IWRES CWRES NPDE DV OCC TIME TADO DGRP PLOT CP  
 NOPRINT ONEHEADER FILE=sdtab

$TABLE ID  
 NOPRINT ONEHEADER FILE=catab  
$TABLE ID AGE SEX RACE WT HT BMI HIV FFM  
 NOPRINT ONEHEADER FILE=cotab  
$TABLE ID V2 MTT BIO NN KM KA VMAX ETA1 ETA2 ETA3 ETA4 ETA5 ETA6 ETA7 ETA8 ETA9 ETA10 ETA11 ETA12 ETA13  
 NOPRINT ONEHEADER FILE=patab

$TABLE ID  
 NOPRINT ONEHEADER FILE=mytab